サンプルアプリケーション01：PowerPointリモコン¶

作成するアプリケーションについて¶

PowerPointのスライドを操作するWindowsアプリケーションと、そのアプリケーションを操作するFireMonkeyモバイルアプリケーションを作成します。

PowerPointのスライドを操作するWindowsアプリケーションの作成¶

プロジェクトの作成¶

新規にVCLフォームアプリケーションを作成します。

フォームの作成¶

フォームにボタン（TButton）を5つと、アクションリスト(TActionList）を配置します。

アクションの作成¶

アクションを5つ作成します。

作成したアクションのNameプロパティとCaptionプロパティを設定します。

ActionRunPresentation … スライドショー
ActionGoToNextSlide … 次のスライド
ActionGoToPreviousSlide … 前のスライド
ActionGoToFirstSlide … 最初のスライド
ActionGoToLastSlide … 最後のスライド

ボタンにアクションを割り当てます。

実装¶

PowerPointに接続する¶

アプリケーションを起動した時にPowerPointに接続します。

まず、フォームのメンバ変数を追加します。

private
  { Private 宣言 }
  FPowerPointApp: OLEVariant;

フォームのOnShowイベントを追加します。

uses System.Win.ComObj;

procedure TForm1.FormShow(Sender: TObject);
begin
  try
    Self.FPowerPointApp := CreateOleObject('PowerPoint.Application');
  except
    on E: Exception do
      ShowMessage('接続できませんでした。' + #13#10 + E.Message);
  end;
end;

PowerPointのスライドを操作する¶

PowerPointを操作するアクションを実装します。

スライドショー … スライドショーを開始します。

procedure TForm1.ActionRunPresentationExecute(Sender: TObject);
begin
  Self.FPowerPointApp.ActivePresentation.SlideShowSettings.Run;
end;

次のスライド … 次のスライドを表示します。

procedure TForm1.ActionGoToNextSlideExecute(Sender: TObject);
begin
  Self.FPowerPointApp.ActivePresentation.SlideShowWindow.View.Next;
end;

前のスライド … 前のスライドを表示します。

procedure TForm1.ActionGoToPreviousSlideExecute(Sender: TObject);
begin
  Self.FPowerPointApp.ActivePresentation.SlideShowWindow.View.Previous;
end;

最初のスライド … 最初のスライドを表示します。

procedure TForm1.ActionGoToFirstSlideExecute(Sender: TObject);
begin
  Self.FPowerPointApp.ActivePresentation.SlideShowWindow.View.First;
end;

最後のスライド … 最後のスライドを表示します。

procedure TForm1.ActionGoToLastSlideExecute(Sender: TObject);
begin
  Self.FPowerPointApp.ActivePresentation.SlideShowWindow.View.Last;
end;

動作確認¶

ここまで完成したら、動作を確認します。

あらかじめPowerPointを起動した状態で、アプリケーションを起動します。

各ボタンをしてスライドショーの表示を確認します。

アプリケーションテザリング機能を追加する¶

作成したアプリケーションをリモートのアプリケーションから操作できるように、アプリケーションテザリングの機能を追加します。

TTetheringManagerコンポーネントとTTetheringAppProfileコンポーネントをフォームに配置します。

TetheringAppProfile1のManagerプロパティを「TetheringManager1」にします。

TetheringAppProfile1のGroupプロパティを「PowerPointRemoteControl」にします。

次に共有するアクションを設定します。

TetheringAppProfile1のActionsプロパティの[...]ボタンを押します。

新規追加ボタンを5回押して、5つ追加します。

追加した5つのアクションのActionプロパティにアクションリストで作成した5つのアクションをそれぞれ設定します。

Windowsアプリケーションを操作するFireMonkeyモバイルアプリケーションの作成¶

作成したWindowsアプリケーションを操作するFireMonkeyモバイルアプリケーションを作成します。

プロジェクトの作成¶

FireMonkeyモバイルアプリケーションのプロジェクトを追加します。

フォームの作成¶

フォームに次のコンポーネントを配置します。

TPanel … Align=Top
- TLabel … Align=Client
- TButton … Align=Right
TGridPanelLayout … Align=Client
- TButton … Align=Client
TActionList
TTimer
TTetheringManager
TTetheringAppProfile

接続処理¶

TetheringAppProfile1のManagerプロパティを「TetheringManager1」に、GroupプロパティをWindowsアプリケーションと同じ「PowerPointRemoteControl」にします。

アクションリストに新しいアクションを作成します。

右上のボタンに作成したアクションを設定します。

アクションのOnExecuteイベントを追加します。

procedure TForm2.ActionConnectExecute(Sender: TObject);
begin
  TetheringManager1.AutoConnect();
end;

次にTimer1のOnTimerイベントを追加します。

procedure TForm2.Timer1Timer(Sender: TObject);
begin
  if TetheringManager1.RemoteProfiles.Count > 0 then
  begin
    Label1.Text := '接続中';
  end
  else
  begin
    Label1.Text := '接続していません。';
  end;
end;